我的U盘里的文件全部变成了隐藏文件，而且不能更改！！

这是因为如果他们有系统属性就无法右键属性设置他们的隐藏属性.

我写的这个批处理可以修改磁盘或文件或文件夹内所有文件的系统属性和隐藏属性,很方便的.

将以下内容复制到记事本,另存为"修改系统属性和隐藏属性.bat"(注意加引号).

用的时候,把要修改属性的磁盘或文件或文件夹,拖到批处理文件的图标上(可以拖很多),然后按提示操作就行了.

注意:请把要更改属性的磁盘或文件或文件夹拖到批处理文件图标内,不要双击运行此批处理.

@echo off
setlocal enabledelayedexpansion
title 修改系统属性和隐藏属性
color f0
mode con: cols=50 lines=25
if "%~1"=="" (
echo 你没有拖入任何磁盘或文件或文件夹
echo 请把要处理的磁盘或文件或文件夹拖到批处理文件图标
echo 不要双击启动批处理
pause
)
:loop
cls
if "%~1"=="" goto :eof
if not exist "%~1" (echo 路径不存在)&pause&shift&goto loop
echo 当前处理的磁盘或文件或文件夹:
echo %~1
echo.
echo 请选择要进行的操作，然后按回车
echo.
echo 加系统和隐藏属性……………………………1
echo 减系统和隐藏属性……………………………2
echo 不处理…………………………………………3
echo.
set /p "c1=选择 (1,2,3) (不输入为!c1!,默认为2):"
if "!c1!"=="1" (set "d=+") else if "!c1!"=="3" (pause&shift&goto loop) else set "d=-"
set "a=%~a1"
if /i "!a:~0,1!"=="d" (
echo.
echo 这是一个文件夹，请选择要进行的操作，然后按回车
echo.
echo 只对该文件夹本身……………………………1
echo 只对该文件夹中的文件夹和文件……………2
echo 对该目录下的一切的文件夹和文件…………3
echo.
set /p "c2=选择 (1,2,3) (不输入为!c2!,默认为1):"
if "!c2!"=="2" (
pushd "%~1"
for /f "delims=" %%i in ('dir /a /b "%~1"') do attrib.exe !d!s !d!h "%%i"
popd
) else if "!c2!"=="3" (
for /f "delims=" %%i in ('dir /a /b /s "%~1"') do attrib.exe !d!s !d!h "%%i"
) else (
attrib.exe !d!s !d!h "%~1"
)
) else (
attrib.exe !d!s !d!h "%~1"
)
pause&shift&goto loop

AUTORUN防御者 查杀并恢复被病毒隐藏的文件

.....
有可能是中毒了,你可以先把
隐藏文件
改过来吧..
开始>>运行>>输入命令
attrib
-s
-h
I:\
/s
/d
(
I
盘为你的U盘
盘符
,改成你自己的
)
显示出U盘所有文件后,你再进去瞧瞧,估计哪些是病毒,删之,如果没重要文件,建议格式化..
.....

中毒!
去下360
U盘专杀,
还是有希望救好的,如果重要就别格,格了毒也还在的!
U盘毒是这样特殊的!

是病毒，nod32可以查杀，若没有安装，可用下列方法处理。
打开任意压缩包，在空白处点一下，按退格键直到界面不再变化，这时你会发现你的U盘在列表中，双击进入，选中其中与文件夹同名的*.EXE文件以及相关的病毒本体，强制删除。此法亦可用于查找、删除、调用隐藏文件或文件夹。