Fortran语言：CHARACTER COMENT(*)*60和CHARACTER ANT*(*)是什么意思？

CHARACTER COMENT(*)*60
意思是，定义一个字符串数组，名字叫 coment，（每个元素的）长度是60，其元素的个数由实参决定。

CHARACTER ANT*(*)
意思是，定义一个字符串，名字叫 ant，其长度由实参决定。

Program Baidu_Thlws
Implicit None
character :: c(5)*60 , a*40 !// a 的长度是40，c 的长度是 60，有5个元素
c(:) = 'cccccccc'
a = 'aaaaaaaaaa'
call sub( c , a )
Contains
Subroutine sub( coment , ant )
CHARACTER COMENT(:)*60
CHARACTER ANT*(*)
Integer :: i
write(*,*) len( coment ) , len(ant) !// 他俩的长度分别是 60 和 40。ant 的长度由实参，也就是 a 决定
write(*,*) ant
Do i = 1 , 5
write(*,*) coment(i)
End do
End subroutine sub
End Program Baidu_Thlws

这样假定长度，假定大小的数组，只能对虚参进行，也就是函数 Subroutine sub( coment , ant ) 列表里的 coment 和 ant。其他变量不能这样定义。

另外，我非常强烈建议你不要使用假定大小数组。这样很容易造成内存泄露。

更科学，更符合新语法的定义是这样：
Character( Len = * ) :: coment(:) , ant

用 coment(:) 来代替 coment(*)，这样的话，子程序会知道 coment 一共有5个元素。

Program Baidu_Thlws
Implicit None
character :: c(5)*60 , a*40 !// a 的长度是40，c 的长度是 60，有5个元素
c(:) = 'cccccccc'
a = 'aaaaaaaaaa'
call sub( c , a )
Contains
Subroutine sub( coment , ant )
Character( Len = * ) :: coment(:) , ant
Integer :: i
write(*,*) len( coment ) , len(ant) !// 他俩的长度分别是 60 和 40。ant 的长度由实参，也就是 a 决定
write(*,*) ant
Do i = 1 , size(coment) !// 这里可以用 size 来获得 coment 的元素，也就是 5
write(*,*) coment(i)
End do
End subroutine sub
End Program Baidu_Thlws