80X86汇编的一个小程序设计

; 本程序通过编译，运行正确
Code Segment
Assume CS:Code,DS:Code
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出一个字符
; 入口：dl=要显示的字符
Enter_Chr proc Near
push ax
mov ah,02h
int 21h
pop ax
ret
Enter_Chr endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出回车换行
Enter_CTLF proc Near
push ax
push dx
mov ah,02h
mov dl,0dh
int 21h
mov dl,0ah
int 21h
pop dx
pop ax
ret
Enter_CTLF endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的低4位二进制数转换成十六进制显示的ASCII码
; 入口：AL
; 出口：AL=转换后的ASCII码
AL_ASCII Proc Near
cmp al,10 ;AL<10?
jb @@To_ASCII ;AL<10，按数字处理
add al,7 ;AL>=10，按大写字母处理
@@To_ASCII: add al,'0' ;转换成相应的数字或大写字母
ret
AL_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的字节数转换成十六进制显示的ASCII码
; 入口：AL
; 出口：AX=转换后的ASCII码
Byte_ASCII Proc Near
push cx
mov cx,4
xor ah,ah ;将AH置0
shl ax,cl ;将AX左移4位
shr al,cl ;将AL右移4位
xchg ah,al
call AL_ASCII ;调用子程序，将AL中的值转换成相应的ASCII码
xchg ah,al
call AL_ASCII
xchg ah,al
pop cx
ret
Byte_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：将AL中的字节数转换成十六进制显示的ASCII码，并在当前光标位置显示
; 入口：AL
; 出口：AX=转换后的ASCII码
ByteD_ASCII Proc Near
push dx
push ax
call Byte_ASCII ;将AL中的字节数转换成十六进制显示的ASCII码
mov dl,al
call Enter_Chr ;显示一个字符
mov dl,ah
call Enter_Chr ;显示一个字符
mov dl,'H'
call Enter_Chr ;显示一个字符
pop ax
pop dx
ret
ByteD_ASCII EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Prompt_Str1 db 'Please input a charactor: $'
Prompt_Str2 db 13,10,'The ASCII code of ('
Charactor db ?,') is $'
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
Input_Chr: Output Prompt_Str1 ;提示输入一个字符
mov ah,1
int 21h
cmp al,13 ;回车?
jz Exit_Proc ;结束程序
mov Charactor,al
Output Prompt_Str2 ;提示显示字符的ASCII码
mov al,Charactor
call ByteD_ASCII ;将AL中的字节数转换成十六进制显示的ASCII码，并在当前光标位置显示
call Enter_CTLF ;输出一个回车、换行
call Enter_CTLF ;输出一个回车、换行
jmp Input_Chr
Exit_Proc: mov ah,4ch ;结束程序
int 21h
String db ?
Code ENDS
END Start ;编译到此结束

print:
mov ah,0
mov cl,10h
div cl
mov cx,ax

mov dl,cl
add dl,30h
mov ah,2
int 21h

mov dl,ch
cmp dl,0ah
jl p_next0
add dl,07h
p_next0:
add dl,30h
mov ah,2
int 21h